10 PRINT TAB(30);"SCHMOO"
20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN NEW JERSEY"
21 PRINT
22 PRINT
23 PRINT
30 PRINT "THIS IS A NEW SCHMOO GAME.  SCHMOOS"
32 PRINT "ARE IMAGINARY CREATURES WHO LOVE"
34 PRINT "BEING SPLATTED WITH JUICY MUD BALLS."
36 PRINT "YOU, BEING A SCHMOO LOVER, TRY TO"
38 PRINT "MAKE SCHMOOS HAPPY BY TOSSING MUD"
40 PRINT "BALLS AT THEM.  YOU HAVE A"
42 PRINT "MECHANICAL MUD SLINGER THAT WILL"
44 PRINT "SLING MUD TO A MAXIMUM DISTANCE"
46 PRINT "OF 46,500 INCHES. YOUR JOB IS TO"
50 PRINT "SET THE MUD SLINGER AT THE CORRECT"
55 PRINT "ELEVATION (0 TO 90) AND THE CORRECT"
60 PRINT "DIRECTIONAL ANGLE (0 TO 360) TO SPLAT THE"
65 PRINT "SCHMOO.  A HIT WITHIN 100 INCHES OF THE SCHMOO"
70 PRINT "WILL SPLATTER HIM."
75 PRINT
90 PRINT
100 K1=0
110 Z=INT(1+RND(1)*4-1E-08)
120 ON Z GOTO 130,140,150,160
130 P=-1
135 Q=-1
138 GOTO 200
140 P=-1
145 Q=1
148 GOTO 200
150 P=1
155 Q=-1
158 GOTO 200
160 P=1
165 Q=1
200 X=(INT(26000*RND(1)+5000))*P
210 Y=(INT(26000*RND(1)+5000))*Q
220 S=0
230 K1=K1+1
240 IF K1 < 2 THEN 400
250 R=INT(7*RND(1)+5)
260 GOTO 400
300 PRINT "THE ELEVATION MUST BE BETWEEN 1 AND 90."
310 GOTO 500
320 PRINT "DIRECTIONAL ANGLE MUST BE FROM 0 TO 360."
340 GOTO 500
350 PRINT "*SCHMOO SPLATTED*";S;" MUD BALLS TOSSED."
351 PRINT
352 PRINT "I SEE ANOTHER SCHMOO.  TO SPLAT"
354 PRINT "HIM, TYPE MUD.  TO QUIT, TYPE QUIT."
356 PRINT
358 INPUT C$
360 IF C$="MUD" THEN 110
361 STOP
362 PRINT "YOU MISSED THE SCHMOO AT (";X;",";Y;")."
364 PRINT "YOUR MUD HIT (";INT(X1);",";INT(Y1);")."
366 PRINT
370 IF K1 < 2 THEN 500
380 IF S >= R THEN 800
390 PRINT "SCHMOO MUD HIT ";R2;"INCHES FROM YOU."
395 GOTO 500
400 PRINT
410 PRINT "COORDINATES OF THE SCHMOO ARE (";X;",";Y;")."
415 IF K1 < 2 THEN 420
417 PRINT "THE SCHMOO IS HAPPY TO BE SPLATTED."
418 PRINT "TO MAKE YOU HAPPY TOO,"
419 PRINT "HE WILL THROW MUD AT YOU."
420 PRINT
500 PRINT "MUD SLINGER ELEVATION";
502 INPUT B
504 PRINT "DIRECTIONAL ANGLE OF MUD SLINGER";
506 INPUT C
520 IF B = 90 THEN 700
530 IF B > 90 THEN 300
540 IF B < 1 THEN 300
550 IF C < 0 THEN 320
560 IF C > (360-(1E-08)) THEN 320
570 S=S+1
580 IF K1 < 2 THEN 595
590 R2=INT(ABS(300*RND(1)*(11-2*S))+90)
595 J=3.1415926535/180
596 D=ABS(INT(93000*SIN(B*J)*COS(B*J)))
610 X1=D*COS(C*3.1415926535/180)
620 Y1=D*SIN(C*3.1415926535/180)
630 D1=SQR((X-X1)^2+(Y-Y1)^2)
640 IF 100 >= D1 THEN 350
650 GOTO 362
700 PRINT "YOU DOPE!  YOU SPLATTED YOURSELF."
710 GOTO 900
800 PRINT "THE SCHMOO HAS SPLATTED YOU!"
802 PRINT "CLEAN UP AND GOODBYE!"
900 END